Der deutsche DCS-BIOS-Thread: Für Simpit-Bastler und solche, die es werden wollen

Ich hatte insgesamt n paar mehr Anzeigen zu betreiben (6-9 Stück).

Das wird dann ja vermutlich mit der bestehenden Bibliothek nicht klappen, oder?

Schwer zu sagen. Es wäre zwar immer nur eine Ziffer gleichzeitig an, aber "So langsam, dass beim Aufruf aus dem Timer Interrupt andere Interrupts so lange blockiert werden, dass die Kommunikation nicht mehr funktioniert" und "so langsam, dass das menschliche Auge ein Flackern sieht" sind zwei sehr unterschiedliche Dinge.

Angenommen, die Library will eine 8 darstellen, das sind 31 Aufrufe von digitalWrite() oder maximal 3100 CPU-Takte. Umgerechnet sind das ca. 200 Mikrosekunden. Wenn du die Refresh-Frequenz der Library also hoch genug setzt, dürfte es einige Anzeigen brauchen, bis du ein Flackern siehst. Die maximale Helligkeit wird allerdings abnehmen, da bei doppelt sovielen Anzeigen jede Anzeige nur noch halb so lang leuchtet.

Ich würde den MAX7219-Chip empfehlen. Lokal zu kaufen lohnt sich nicht, da zahlst du für kleine Mengen 8 bis 10 Euro pro Stück. Die günstigste Möglichkeit, so ein Ding zu bekommen, scheint im Moment dieses Modul zu sein.

Ian;2767495']

Ich würde den MAX7219-Chip empfehlen. Lokal zu kaufen lohnt sich nicht, da zahlst du für kleine Mengen 8 bis 10 Euro pro Stück. Die günstigste Möglichkeit, so ein Ding zu bekommen, scheint im Moment dieses Modul zu sein.

Jup... MAX7219 wär das Ding der Wahl.

Meine Empfehlung: Dieses Komplettmodul

Ja, das gibt's auch für ein Drittel des Preises beim Chinamann, aber ich hab' "support your local dealer" im Hinterkopf. :) Und selbst für 6euroschnick lohnt das Selbstlöten IMO nicht wirklich. Soll jetzt keine Kritik an Deinem Alibaba-Link sein, Ian. Nur eine allg. Meinung von mir.

Stimmt, bei den Dingern gibt's ja die 7-Segment-Anzeigen gleich mit dabei (zumindest wenn man 4-stellige haben will). So ein Ding hab ich auch bei mir liegen, hat bei Aliexpress 1,40 € gekostet.

Der Trade-off, aus China oder Deutschland zu bestellen, sieht ungefähr so aus:

Aus China ist's ca. 5 Euro günstiger, dafür wartet man drei bis vier Wochen statt drei bis vier Tage.

Und natürlich sollte man aus China keinen Support erwarten (höchstens die Versendung eines Ersatzartikels, wenn der erste defekt ist -- aber dann muss man wieder vier Wochen warten).

Hallo zusammen,

ich habe eine Frage zum Arduino Mega 2560.

Ich habe mit einem Arduino Uno und drei MAX7219 Displays schön meine beiden VHF und die UHF Frequenz zum anzeigen gebracht. Da ich aber mehr digitale Eingänge brauche für die Rotary Encoder, bin ich auf ein Arduino Mega 2560 gewechselt.

Ich habe meinen Code auf das Mega Board geladen, den richtigen COM Port ausgewählt und gesetzt und ich sehe auch das Daten am Board ankommen. Allerdings werden meine Frequenzen nicht mehr angezeigt. Entweder nur nullen oder garbage.

Muss ich beim Einsatz des Mega Boards irgendwas ändern, z.B. Code?

Ich benutze Windows 10.

In meiner connect-serial-port.cmd Datei, habe ich ich Baud auf 500000 gesetzt. Stand beim Uno auf 250000 per default und hatte funktioniert. Diese Änderung auf 500000 brachte aber keine Änderung.

Dann habe ich mir unter "Geräte" die Einstellungen des Mega Boards angeguckt und dort stehen die Bits pro Sekunde auf 9600. War aber beim Uno Board auch so und da funktionierte es. Könnte diesen Wert auch nicht auf 500000 setzen, da mir nur ein maximaler Wert von 128000 möglich ist.

Wäre super, wenn hier irgend jemand eine Idee hätte. Habe jetzt ein paar Stunden rumprobiert, aber bekomme es nicht zum Laufen mit dem Mega Board. Hänge ich das Uno Board wieder hin, läuft es sofort :(

Danke im Voraus!

Pete

In meiner connect-serial-port.cmd Datei, habe ich ich Baud auf 500000 gesetzt. Stand beim Uno auf 250000 per default und hatte funktioniert. Diese Änderung auf 500000 brachte aber keine Änderung.

 

Dann habe ich mir unter "Geräte" die Einstellungen des Mega Boards angeguckt und dort stehen die Bits pro Sekunde auf 9600. War aber beim Uno Board auch so und da funktionierte es. Könnte diesen Wert auch nicht auf 500000 setzen, da mir nur ein maximaler Wert von 128000 möglich ist.

Aktuelle Versionen von DCS-BIOS benutzen immer 250000 bps. Wenn was anderes in der connect-serial-port.cmd steht, kann das gar nicht funktionieren. Die Einstellungen im Gerätemanager sind egal, weil die connect-serial-port.cmd mit dem "mode"-Befehl die passende Bitrate setzt.

Poste hier mal den Code, der auf dem Uno funktioniert, und den, der dann auf dem Mega nicht funktioniert. Normalerweise musst du den Code nicht ändern, es reicht, in der Arduino-IDE das Board auf "Mega 2560" zu setzen und den COM-Port auszuwählen, an dem der Mega dranhängt.

Es könnte eine von diesen Fehlerquellen sein:

• Irgendwas ist beim Upload auf den Mega schiefgegangen (unwahrscheinlich, da ja zumindest Müll auf den Displays ankommt)
  
• Wenn du auf dem Mega gleich die Rotary Encoder hinzugefügt hast, könnte es an dem neuen Code liegen (sollte im DCSBIOS_IRQ_SERIAL-Modus nicht passieren, mit DCSBIOS_DEFAULT_SERIAL ist das durchaus möglich)
  
• Beim Umbau auf den Mega irgendwelche Leitungen vom MAX7219 vertauscht (z.B. CLOCK und DATA)
  

Ich möchte mir die A-10C CDU bauen. Habe mittlerweile schon etliche Panels selbst gebaut. Das Bedienen des CAD Programm und der CNC Fräse haben reichlich Nerven bis jetzt gekostet. Nur, zum Programmieren bin ich einfach zu doof. Ich habe jetzt hier im Forum alles durchgelesen, verstehe aber nur Bahnhof. :cry:

Könnte irgend jemand so lieb sein, und mir eine Liste zusammenstellen, welche Teile ich überhaupt brauche? Welches Display...etc.?

Und welche Software ich für was brauche?

Und dann müsste man mich noch an die Hand nehmen und mir step by step erklären, was ich wo und wie reinschreiben / programmieren soll. Wenn alles läuft, würde ich sogar folgendes Angebot machen.

Ich würde einen Thread öffnen, der nicht über 15 Seiten zur Problemlösung dient, sondern nur als Art Bauanleitung dienen soll. Für mich wäre das echt sehr hilfreich, wenn es soetwas geben würde. Also, keine Problemdiskusionen sondern nur Lösungen. Verständlich erklärt für jedermann. :smilewink:

Also für Leute wie ich.......über 40 jährige.

Hier kommt der Code, der auf dem Uno funktioniert:

#define DCSBIOS_IRQ_SERIAL

#include "DcsBios.h"
#include <LedControl.h>

//pin 3 is connected to the DataIn 
//pin 5 is connected to the CLK 
//pin 4 is connected to LOAD
LedControl lc=LedControl(3, 5, 4, 1); 

/* VHF AM */
void onVhfamFreq1Change(char* newValue) {
  lc.setChar( 0, 6, newValue[0], false );
  lc.setChar( 0, 5, newValue[1], false );
}
DcsBios::StringBuffer<2> vhfamFreq1StrBuffer(0x1190, onVhfamFreq1Change);

void onVhfamFreq2Change(unsigned int newValue) {
  lc.setChar( 0, 4, newValue, true );
}
DcsBios::IntegerBuffer vhfamFreq2Buffer(0x118e, 0x00f0, 4, onVhfamFreq2Change);

void onVhfamFreq3Change(unsigned int newValue) {
    lc.setChar(0, 3, newValue, false);
}
DcsBios::IntegerBuffer vhfamFreq3Buffer(0x118e, 0x0f00, 8, onVhfamFreq3Change);

void onVhfamFreq4Change(char* newValue) {
   lc.setChar( 0, 2, newValue[0], false );
   lc.setChar( 0, 1, newValue[1], false );
}
DcsBios::StringBuffer<2> vhfamFreq4StrBuffer(0x1192, onVhfamFreq4Change);


void setup() {
 DcsBios::setup();

 //This initializes the MAX7219 and gets it ready of use:
 lc.shutdown( 0, false ); //turn on the display
 lc.setIntensity( 0, 8 );//set the brightness 
 lc.clearDisplay(0); //clear the display 

 lc.setChar( 0, 0, '8', false );
 lc.setChar( 0, 1, '8', false );
 lc.setChar( 0, 2, '8', true );
 lc.setChar( 0, 3 ,'8', false );
 lc.setChar( 0, 4, '8', false );
 lc.setChar( 0, 5, '8', false );
}

void loop() {
 DcsBios::loop();
}

Den Upload auf den Mega habe ich mehrmals gemacht, da ich auch dachte das was schiefgegangen ist. Meistens werden nur 888888 (wie initialisiert) angezeigt. Wenn ich an den Kabeln wackel, wir manchmal was anderes angezeigt. Sehr komisch, denn es sind die gleichen Kabel die beim Uno funktionieren. Die digitalen Eingänge auf dem Mega scheinen auch OK zu sein, denn ich kann dort ein LED gewollt zum blinken bringen, je nachdem welchen Eingang ich ansteuere. Dachte anfangs, dass eventuell Eingänge kaputt sind.

Rotary Encoder hatte ich weggelassen, da ich erstmal die Anzeige generell testen wollte.

Leitungen hab ich glaub ich nicht vertauscht. Auch schon mehrmals gemacht und wenn ich die gleichen Leitungen an die gleichen digitalen Eingänge auf dem Uno stecke, funktioniert es.

Hoffe der Code gibt Aufschluß.

Hallo an alle!

Ich würde eure Hilfe für die Darstellung des Ka-50 "UV26" mittels 7-Segment-Modul (8-digits mit MAX7219 Chip) an einem Mega 2560 benötigen

http://www.ebay.de/itm/272279983203?_trksid=p2057872.m2749.l2649&ssPageName=STRK%3AMEBIDX%3AIT

Hab Arduino IDE soweit installiert und das richtige Board und Port in den Settings gewählt. Dann wurde das MasterCaution example geöffnet und der passende Codeschnippsel eingesetzt für das UV26:

/* use '#define DCSBIOS_DEFAULT_SERIAL' instead if your Arduino board
*  does not feature an ATMega328 or ATMega2650 controller.
*/

#include "DcsBios.h"
#include <LedControl.h>

void onUv26DisplayChange(char* newValue) {
   /* your code here */
}
DcsBios::StringBuffer<3> uv26DisplayBuffer(0x1812, onUv26DisplayChange);


}

Beim compillieren bekomme ich dann eine Fehlermeldung:

MasterCaution.ino:6:24: fatal error: LedControl.h: No such file or directory

Fehlt da noch was von der Library? Ich steh grad voll aufm Schlauch...

So einfach scheints dann leider doch nicht zu gehen:cry:

Was muss denn bei /*your code here*/ noch eingesetzt werden?

Wie kann ich denn die Ausgabe-Digits definieren? Hab ja deren 8 an dem Modul und kann Bauartbedingt nur die "mittleren" drei davon verwenden, weil ich das Modul sonst nicht in mein UV26 verbaut bekomme.

Ist es mit DCS-BIOS denn überhaupt möglich, sämtliche Daten des UV26 auszugeben? Dort werden ja nicht nur die verbleibende Restmenge an Flares angezeigt sondern auch die Ausstoßintervalle, Dauer und Menge programmiert und somit auch im jeweiligen Modus ausgegeben an dem 3-stelligen Display.

Um beliebige Hardware (in diesem Fall den MAX7219) mit DCS-BIOS zu verwenden, ist der erste Schritt im Allgemeinen, die Hardware erstmal ohne DCS-BIOS zum Laufen zu bringen. Danach hat man verstanden, wie man die benutzt, und weiß, dass die Schaltung richtig aufgebaut ist.

Um den MAX7219 mit Arduino-Boards anzusteuern, gibt es die LedControl-Library. Da die in der offiziellen Liste eingetragen ist, kannst du die einfach über "Sketch -> Include Library... -> Manage Libraries..." in der Arduino-IDE installieren.

Mit der Dokumentation und den mit der LedControl-Library mitgelieferten Beispielen kann man dann erstmal ein einfaches Testprogramm bauen:

https://gist.github.com/jboecker/e2d3a1972a8ac442f923955c79858c3c

Das zeigt eine Sekunde lang "88888888" an, und zeigt danach an, welche Ziffer welche interne Nummer hat:

Mit dem Wissen, welchen Initialisierungscode man in setup() braucht und wie man mit setChar() ein Zeichen auf das Display platzieren kann, lässt sich das jetzt mit DCS-BIOS kombinieren:

https://gist.github.com/jboecker/298e471192bc3f9425acb817eb359057

5OKPht_tpME

Vielen Dank [FSF]Ian für die diese superschnelle detaillierte Anleitung bzw. gleich den fertigen Code:thumbup::thumbup::thumbup:

Das hätte ich niemals hinbekommen und jetzt finde ich damit einen Einstieg in DCS-BIOS.

Das compilieren hat alles soweit hingehauen, nur bekomme ich beim Ausführen folgende Fehlermeldung:

fotos hochladen

Die connect-serial-port.cmd habe ich schonmal in der Firwall auf Vollzugriff konfiguriert. Woran kanns denn noch liegen?

Die Warnmeldung ("Couldn't compute FAST_CWD pointer") ist normal unter Windows 10. Sollte aber trotzdem funktionieren (hab selbst Windows 10).

Sobald du DCS startest und in einem Ka-50 sitzt (und das Spiel nicht pausiert ist), sollten Daten übertragen werden -- sieht man einerseits im Konsolenfenster, andererseits an der blinkenden RX Led auf dem Arduino-Board (und hoffentlich auch daran, dass das Display die Werte vom UV-26 anzeigt).

Pixar: sorry für die späte Reaktion. Ich hab deinen Sketch gerade mal auf einem Mega ausprobiert, funktioniert einwandfrei (kleiner Bug: du überschreibst Ziffer 0 nie, so dass z.B. 125,125 MHz als "125.1258" angezeigt wird).

Entweder ist an deinem Mega was kaputt oder die Kabel, die bei deinem Uno guten Kontakt bekommen, haben mit der Buchse auf dem Mega Probleme. Du kannst ja mal versuchen, andere Pins auf dem Mega zu benutzen (vielleicht haben die Kabel an anderen Stellen besseren Kontakt). Als Test würde ich einen der Beispiele von der LedControl-Library nehmen, dann musst du zum Testen nicht erst DCS starten.

Diese Buchsenleisten haben meiner Erfahrung nach nie so richtig guten Kontakt mit den typischen Jumper Wires ("DuPont-Kabel"), die man so auf eBay bekommt. Die passenden Stiftleisten (sowas hier) funktionieren dagegen zuverlässig.

Was relativ gut funktioniert, ist das Plastikteil in die Mitte der Stiftleiste zu schieben, so dass beide Enden ungefähr gleich lang sind. Dann die Stiftleiste in die Buchsenleiste des Mega stecken, und ein DuPont-Kabel mit Buchse oben drauf. Oder einfach direkt einen Draht per Lötverbindung oder Wire Wrap an die Stiftleiste anschließen.

Ok, wusste ich nicht, dass die Fehlermeldung in Ordung ist.

Das Segmentmodul zeigt glaub ich nix an, weil ich es laut diesem Manual verkabelt habe:doh::

bilder upload

Jetzt stehen in deinem Sketch aber die belegten Pins 2,3,4,1 wenn ich das richtig verstehe.

Hast Du vielleicht einen Link mit einer guten Arduino Pinoutbeschreibung. Weil die Beschreibungen, welche ich gefunden habe, verwirren mich sehr. Hab Angst an die falschen Pins anzuschließen und mir was weg zu brutzeln...

Wo muss ich denn Vcc, GND,Dout,Load,CLK genau Anschließen für deinen Sketch? Bzw. wo in welcher Zeile in deiner DCSBiosKa50UV26Test.ino kann man die Pinnbelegung anpassen? Ich find da nix selbsterklärendes.

In der MAX7219SegmentId.ino müsste das hier sein, richtig?:

/*
pin 2 = DataIn 
pin 3 = CLK 
pin 4 = LOAD 
1 = Anzahl hintereinandergeschalteter MAX7219-Chips
*/

Die entscheidende Zeile ist die hier:

LedControl lc=LedControl(2,3,4,1);

Die erste Zahl (2) gibt den DATA_IN pin an, die zweite (3) den CLOCK pin und die dritte (4) ist der LOAD/CS pin. Die vierte Zahl (1) ist die Anzahl der hintereinandergeschalteten MAX7219-Chips.

Siehe auch: http://playground.arduino.cc/Main/LedControl#Setup

Auf dem 8-stelligen MAX7219-Modul, was auf eBay und AliExpress gängig ist, sind die Pins wie folgt bezeichnet:

DATA_IN: "DIN"

CLK: "CLK"

LOAD/CS: "CS"

EDIT: Für das Schaltbild in deinem Post müsste die Zeile so aussehen:

LedControl lc=LedControl(22, 26, 24, 1);

EDIT 2: Solange du "VCC" mit 5V und "GND" mit Masse verbindest, kann da bei diesem Modul nichts kaputt gehen, egal an welche Arduino-Pins du die anderen Kabel hängst. Es kann nur die Daten falsch interpretieren.

Danke für die Erklärung. Jetzt lichtet sich das ganze System in DCS-BIOS langsam.

Also mit deiner MAX7219SegmentId.ino werden mir jetzt die Digit-IDs angezeigt wie auf deinem Beispielfoto.

Wenn ich jedoch die DCSBiosKa50UV26Test.ino (mit der jetzt funktionierenden Einstellung: LedControl lc=LedControl(22,26,24,1) "uploade" und connect-serial-port.cmd starte, leuchtet leider nix am Modul bei gestarteter Ka-50 Mission (unpaused).

Hab nochmal die export.lua gecheckt auf die Passage:

dofile(lfs.writedir()..[[scripts\DCS-BIOS\BIOS.lua]])

Unter C:\Users\username\Saved Games\DCS.openbeta\Scripts\DCS-BIOS

sind die entpackten files von dcs-bios-v0.5.0.zip aus dem Ordner DCS-BIOS reinkopiert worden.

Die Firewall hab ich temporär mal deaktiviert zur Sicherheit.

Im CMD von der gestarteten connect-serial-port.cmd rührt sich auch nichts weiter während der Mission. Muss ich die connect-serial-port.cmd als Admin starten? Weil ich nämlich eine Fehlermeldung bekomm, wenn ich dies versuche.

Die RX-Led leuchtet auch kein bisschen währenddessen.

Eine wirklich schwere Geburt wieder das Ganze...:music_whistling:

Sorry für das schleppende Vorranschreiten...ich will doch nur die drei dämlichen Digits leuchten sehen:cry:

Hast du die connect-serial-port.cmd editiert und die richtige COM-Port-Nummer eingetragen?

Benutzt außer DCS-BIOS noch irgendwas anderes (Helios, TacView, etc.) die Export.lua?

Die connect-serial-port.cmd musst du nicht als Admin starten.

Ansonsten poste mal deine dcs.log.

Die connect-serial-port.cmd hatte ich auf Com-port 3 editiert. Der Com-port müsste ja stimmen sonst hätte ich ja den Sketch auch nicht uploaden können auf das Arduino. Oder könnte es sein, dass der Port doch tatsächlich ein anderer ist, als unter dem Gerätemanager angezeigt wird?

In der Export.lua sind halt noch paar Sachen die ich am Laufen habe:

dofile("./Scripts/Opencockpits/Opencockpits.lua")

dofile ( lfs.writedir()..'Scripts\\Tacnoworld_UR_DCSW.luac' )

dofile(lfs.writedir()..[[scripts\DCS-BIOS\BIOS.lua]])

dofile(lfs.writedir()..'../AriesWings/AriesRadio.luac')

local SimShakerlfs=require('lfs'); dofile(SimShakerlfs.writedir()..'Scripts/SimShaker.lua')

dofile(lfs.writedir()..[[scripts\SimShaker-export-core\ExportCore.lua]])

Und Helios natürlich auch.

Hab die jetzt mal alle auskommentiert, sodaß nur noch dofile(lfs.writedir()..[[scripts\DCS-BIOS\BIOS.lua]]) aktiv war. Hat auch nichts gebracht.

Kann es sein, dass trotz temporär deaktivierter Firewall, die connect-serial-port.cmd aus irgendwelchen Gründen trotztdem keine Verbindung bekommt. Ich kappier grad nicht wo der Fehler grundsätzlich begründet liegt...

dcs.log:

Hab den Fehler gefunden und jetzt flutscht das:).

In der dcs.log wurde dieser Fehler ausgeworfen:

Can't execute Lua file C:\Users\invicta\Saved Games\DCS.openbeta\Scripts\Export.lua - [string "C:\Users\invicta\Saved Games\DCS.openbeta\Scripts\Export.lua"]:1061: attempt to call field '?' (a nil value)

In der Export.lua habe ich dann die Zeile auskommentiert zu:

--os.setlocale("ISO-8559-1", "numeric")

Anscheinend zwickt sich da was seit dem 1.5.5 Openbeta Update in der Export.lua.

Post #85:

https://forums.eagle.ru/showthread.php?t=175028&page=9

Vielen Dank Ian!!!:thumbup: Jetzt kann ich das UV26 endlich komplettieren, weil ED es ja in der Vergangenheit nicht hinbekommen hat, die Funktion per SIOC zu integrieren.

Kanns kaum erwarten das Modul einzupflanzen:)

Grüße

Terrorvogel

Reputation inbound...

Hallo zusammen,

ich will mich nach Euren Vorgaben auch mal an die 7 Segment anzeigen wagen... :thumbup:

Nun habe ich ein kleines Problem:

Ich habe bereits mit DCS -BIOS mehrere Schalter, LED und einen Servo angesteuert.

hier der Code im Sketch:

und der Code für das UV26 mit dazu:

Wie sieht denn der Code zusammengefügt aus, also ist das egal wo ich den zweiten Code in den Sketch kopiere?! :helpsmilie:

Danke für Eure Hilfe und viele Grüße

Tronix

Die Reihenfolge ist ziemlich egal, weil die meisten Elemente sich nicht gegenseitig referenzieren. In C++-Code müsste normalerweise die Definition der Callback-Funktionen (z.B. "void onUv26DisplayChange(..){...}") vor der Instanziierung des Stringbuffers kommen, der sie verwendet ("DcsBios::StringBuffer<3> uv26DisplayBuffer..."), aber die Arduino-IDE fügt hinter den Kulissen automatisch forward declarations ein, bevor der Code compiliert wird, so dass selbst das egal ist.

Wenn du die folgenden Randbedingungen beachtest, müsste alles klappen:

• Alle #include-Zeilen müssen noch vor der ersten Zeile auftauchen, die etwas daraus verwendet (also z.B. "#include <LedControl.h>" vor "LedControl lc=..."). Deshalb schreibt man die normalerweise alle an den Anfang der Datei.
  
• Die Zeilen "#include <Servo.h>" und "#define DCSBIOS_IRQ_SERIAL" müssen vor dem "#include <DcsBios.h>" stehen, weil DCS-BIOS davon sonst nichts mitbekommt.
  
• Natürlich kannst du die setup()- und die loop()-Funktion nicht zweimal definieren, also einfach beide zusammenfügen (und nur einen Aufruf von DcsBios::setup() bzw. DcsBios::loop() behalten :) )
  

Hi Ian,

danke für die Info...

kannst Du mir ggf. aus meinen beiden Code - Schnip­sel mal die "richtige" zusammenbasteln,

damit ich eine Referenz habe? Kenn mich in C++ überhaupt nicht auskenne... :cry:

Oder ist das hier so richtig:

Danke... :thumbup:

Richtig kann's schonmal nicht sein, weil es nicht kompiliert :P

Das hier sollte funktionieren:

#include <Servo.h>

#define DCSBIOS_IRQ_SERIAL
#include "DcsBios.h"

DcsBios::Switch2Pos r800EmerRcvr("R800_EMER_RCVR", 5);
DcsBios::Switch2Pos r800Adf("R800_ADF", 4);
DcsBios::Switch2Pos abrisPower("ABRIS_POWER", 11);
DcsBios::Switch2Pos hsiDhDtaManualAuto("HSI_DH_DTA_MANUAL_AUTO", 9);
DcsBios::Switch2Pos laserMode("LASER_MODE", 8);
DcsBios::Switch2Pos opPitotPortHeat("OP_PITOT_PORT_HEAT", 7);
DcsBios::Switch2Pos opPitotRamHeat("OP_PITOT_RAM_HEAT", 6);
DcsBios::Switch2Pos scRotorRpmBtn("SC_ROTOR_RPM_BTN", 3);
DcsBios::ServoOutput apuTemp(0x191c, 2, 540, 2550);
DcsBios::LED raltSafeAltLamp(0x184c, 0x1000, 12);
const byte engSelectorPins[4] = {53, 51, 49, 47};
DcsBios::SwitchMultiPos engSelector("ENG_SELECTOR", engSelectorPins, 4);
const byte opNavLightsPins[5] = {45, 43, 41, 39};
DcsBios::SwitchMultiPos opNavLights("OP_NAV_LIGHTS", opNavLightsPins, 4);
DcsBios::Switch3Pos engStartupMode("ENG_STARTUP_MODE", 50, 52);
DcsBios::Switch2Pos r800AmFm("R800_AM_RM", 4, 8);

#include "LedControl.h"
LedControl lc=LedControl(2,3,4,1);


void onUv26DisplayChange(char* newValue) {
   /* set digit 4 to first character (newValue[0]) */
   lc.setChar(0, 4, newValue[0], false);
   
   /* set digit 3 to second character */
   lc.setChar(0, 3, newValue[1], false);
   
   /* set digit 2 to third character */
   lc.setChar(0, 2, newValue[2], false);
}
DcsBios::StringBuffer<3> uv26DisplayBuffer(0x1812, onUv26DisplayChange);


void setup() {
   lc.shutdown(0,false);
   /* Set the brightness to a medium values */
   lc.setIntensity(0,8);
   /* and clear the display */
   lc.clearDisplay(0);
   
   DcsBios::setup();
}

void loop() {
   DcsBios::loop();
}

Copy&Paste funktioniert gut für die einfachen Sachen, aber sobald es um etwas komplexere Dinge geht (wie z.B. Displays), wo man auch in setup() passenden Initialisierungscode braucht, sollte man schon ein paar Grundkenntnisse in C++ mitbringen (was sind Funktionen, Klassen, Variablen, globale vs. lokale Variablen).

Leider kann ich dir keine deutschen Tutorials empfehlen, weil ich mich da überhaupt nicht auskenne. Wenn Englisch kein Problem ist, gibt es auf arduino.cc ein paar Einführungen in C++ (die reden von der "Arduino Language" und meinen damit die Untermenge von C++, die auf Mikrocontrollern sinnvoll ist, zusammen mit der Wiring-Library (digitalWrite() und co.) und der Arduino-IDE).

Ich kann auch schlecht sagen, was der einfachste oder schnellste Weg ist, sich solche Kenntnisse von Grund auf anzueignen. Ich selbst hab das Programmieren über mehrere Jahre und Programmiersprachen hinweg durch viel Herumspielen und Trial & Error gelernt (in der Grundschule hatte ich viel Zeit und keinen Internetanschluss), bin also ganz klein angefangen (Batch-Dateien unter DOS) und hab mich langsam zu komplexeren Sachen vorgearbeitet, wobei ich immer einen Teil der Konzepte der neuen Sprache bereits kannte.

Vielleicht gibt es hier ja jemanden, der selbst in letzter Zeit mit dem Thema neu angefangen hat und ein gutes Buch und/oder Online-Ressourcen auf Deutsch empfehlen kann.

Egal welche Informationsquelle man benutzt, selber Fehler machen, suchen und beheben gehört auf jeden Fall dazu. Irgendwann lernt man dann automatisch, die manchmal kryptischen Fehlermeldungen des Compilers zu lesen, den Fehler auch in der Zeile davor zu suchen, und viele Fehler innerhalb von Sekunden zu beheben, weil man sie schon dreimal selber gemacht hat.

Meiner Erfahrung nach braucht man auch ein konkretes Projekt, das man in der jeweiligen Sprache umsetzen will, aber das ist bei Dir ja vorhanden. Ich hab noch keine Programmiersprache gelernt, ohne dass ich gerade ein Projekt hatte, was in dieser Programmiersprache einfacher umzusetzen war, als in denen, die ich vorher schon kannte.

PS: Codebeispiele sollten in

-Tags gesetzt werden, das macht es lesbarer und schaltet die Smileys aus. Es hilft außerdem für die Lesbarkeit von Code enorm, wenn der eingerückt ist (entweder gleich selbst einrücken, was man sich sowieso angewöhnen sollte, oder in der Arduino-IDE: Tools -> Auto Format bzw. Ctrl+T).

vielen Dank für deine Hilfe und natürlich den Code, Ian... :thumbup:

Ja sich in so eine "Sache" einzuarbeiten kostet viel Zeit und Nerven, deshalb sind wir Hobby Bastler auf solche Experten wie DU einer bist angewiesen und es ist total toll das man in der Community sooo viel Hilfe bekommt.

Wir Laien würden das ohne Euch echt nicht hin bekommen... :cry:

Ich teste das ganze mal und dann versuche ich mich mal noch an dem 7 Segmenten für das Waffenpanel, denn dazu muss ich dann noch ein LED Display Modul MAX7219 ansteuern und den Code dafür raus bekommen... :(

Ich denke da bin ich dann noch mal auf deine Hilfe angewiesen... :helpsmilie::beer:

Hi Ian,

so ich habe jetzt den Code vom UV26 um das Weapon Panel erweitert.

#include <Servo.h>

#define DCSBIOS_IRQ_SERIAL
#include "DcsBios.h"

DcsBios::Switch2Pos r800EmerRcvr("R800_EMER_RCVR", 5);
DcsBios::Switch2Pos r800Adf("R800_ADF", 4);
DcsBios::Switch2Pos abrisPower("ABRIS_POWER", 11);
DcsBios::Switch2Pos hsiDhDtaManualAuto("HSI_DH_DTA_MANUAL_AUTO", 9);
DcsBios::Switch2Pos laserMode("LASER_MODE", 8);
DcsBios::Switch2Pos opPitotPortHeat("OP_PITOT_PORT_HEAT", 7);
DcsBios::Switch2Pos opPitotRamHeat("OP_PITOT_RAM_HEAT", 6);
DcsBios::Switch2Pos scRotorRpmBtn("SC_ROTOR_RPM_BTN", 3);
DcsBios::ServoOutput apuTemp(0x191c, 2, 540, 2550);
DcsBios::LED raltSafeAltLamp(0x184c, 0x1000, 12);
const byte engSelectorPins[4] = {53, 51, 49, 47};
DcsBios::SwitchMultiPos engSelector("ENG_SELECTOR", engSelectorPins, 4);
const byte opNavLightsPins[5] = {45, 43, 41, 39};
DcsBios::SwitchMultiPos opNavLights("OP_NAV_LIGHTS", opNavLightsPins, 4);
DcsBios::Switch3Pos engStartupMode("ENG_STARTUP_MODE", 50, 52);
DcsBios::Switch2Pos r800AmFm("R800_AM_RM", 4, 8);

#include "LedControl.h"
//Pins sind beliebig auswählbar
//Die erste Zahl (22) gibt den DATA_IN pin an, 
//die zweite     (26) den CLOCK pin 
//und die dritte (24) ist der LOAD/CS pin. 
//Die vierte Zahl(1) ist die Anzahl der hintereinandergeschalteten MAX7219-Chips.

LedControl lc=LedControl(22,26,24,1); //DIN,CLK,LOAD,# OF IC's

//mit MAX7219SegmentId.ino die jeweiligen Digits-Nummern anzeigen lassen
//und dann unten in lc.setChar() einsetzen
// IDs von MAX7219Segment:
//7 6 5 4 3 2 1 0

void onUv26DisplayChange(char* newValue) {
   /* set digit 4 to first character (newValue[0]) */
   lc.setChar(0, 7, newValue[0], false);

   /* set digit 3 to second character */
   lc.setChar(0, 6, newValue[1], false);

   /* set digit 2 to third character */
   lc.setChar(0, 5, newValue[2], false);
}
DcsBios::StringBuffer<3> uv26DisplayBuffer(0x1812, onUv26DisplayChange);

void onWeaponsDisplayCannonRemainChange(char* newValue) {
   /* set digit 4 to next first character (newValue[0]) */
   lc.setChar(0, 3, newValue[0], false);

   /* set digit 3 to second character */
   lc.setChar(0, 2, newValue[1], false);
}
DcsBios::StringBuffer<2> weaponsDisplayCannonRemainBuffer(0x188c, onWeaponsDisplayCannonRemainChange);

void onWeaponsDisplayWeaponRemainChange(char* newValue) {
   /* set digit 2 to third character (newValue[0]) */
   lc.setChar(0, 1, newValue[0], false);

   /* set digit 0 to last character */
   lc.setChar(0, 0, newValue[1], false);
}
DcsBios::StringBuffer<2> weaponsDisplayWeaponRemainBuffer(0x188a, onWeaponsDisplayWeaponRemainChange);


void setup() {
 lc.shutdown(0,false);
 /* Set the brightness to a medium values */
 lc.setIntensity(0,8);
 /* and clear the display */
 lc.clearDisplay(0);
 
 DcsBios::setup();
}

void loop() {
 DcsBios::loop();
}

Das funktioniert auch super... :thumbup:

Jetzt will ich das zweite LED Display Modul MAX7219 ansteuern. Ich habe es nach diesem Schaltplan verkabelt:

(Quelle:http://forum.hobbycomponents.com/viewtopic.php?f=75&t=1789)

dann haben wir ja gelernt, dass man in der "LedControl" die Anzahl hintereinandergeschalteter MAX7219-Chips angibt!

In meinem Fall:

LedControl lc=LedControl(22,26,24,2); //DIN,CLK,LOAD,# OF IC's

Und jetzt kommt das Problem, wie spreche ich denn das zweite Modul an?!

Irgendwie hat das glaube ich mit der Funktion zu tun, oder?!

int LedControl::getDeviceCount();

Habe das ganze WE im Internet recherchiert, aber keinen "richtigen" Lösungsansatz gefunden... :cry:

Kannst Du mir bitte noch mal eine Lösung darstellen?! :helpsmilie:

Vielen Dank und viele Grüße

Tronix

Der erste Parameter von setDigit bzw. setChar gibt an, welchen MAX7219 du ansprechen willst. 0 ist der erste, 1 der zweite usw.

lc.setDigit(0, 7, 9, false); // Ziffer 7 auf dem ersten MAX7219 auf '9' setzen
lc.setChar(1, 4, '3', false); // Ziffer 4 auf dem zweiten MAX7219 auf '3' setzen